Ini Dia Fungsi Terbilang Bahasa Indonesia VB.Net Ini Dia Fungsi Terbilang Bahasa Indonesia VB.Net - Berguru IT - Tutorial Visual Basic, Networking, Tips dan Trik
VB.Net

VB.Net Tutorial Untuk pemula

Instant Article

Cara Membuat Instant Article Untuk Blogger

logo

Ini Dia Fungsi Terbilang Bahasa Indonesia VB.Net

Cara Membuat Fungsi Terbilang Bahasa Indonesia VB.Net, Cara memasang fungsi terbilang vb.net
Cara Membuat Fungsi Terbilang Bahasa Indonesia VB.Net
Fungsi Terbilang Bahasa Indonesia VB.Net - Fungsi ini sangat diperlukan dalam sistem keuangan, transaksi keuangan mamupun laporan keuangan, oleh sebab itu kita sebagai programmer wajib mempunyai atau menyertakan program yang bisa menyatakan angka (satuan, puluhan, ribuan, jutaan, milyaran) menjadi sebuah kalimat terbilang pada aplikasi yang kita buat.

Fungsi terbilang paling sering kita temukan pada transaksi keuangan seperti pada nota, kwitansi, invoice, billing dan laporang keuangan. Fungsi terbilang sendiri adalah untuk mengkonversi nilai atau nominal yang ada di transaksi keuangan menjadi kalimat terbilang sehingga seseorang tidak mudah untuk merubah nilai atau nominal sesuka hati.

Untuk membuat fungsi terbilang jika anda tidak mau ribet bikin dari awal anda bisa ikuti langkah-langkah dibawah ini untuk membuat fungsi terbilang.

Baca juga :

Cara Membuat Fungsi Terbilang Bahasa Indonesia VB.Net

Buat kamu yang ingin membuat atau memasang fungsi terbilang ke programnya, silahkan ikuti langkah demi langkah berikut ini : (Jangan lupa Kopi dan Gorengan biar ga bosen).

1. Buat Project Baru di VB.Net

Pada tutorial ini saya menggunakan aplikasi visual studio 2013, jadi apabila ada perbedaan gambar dengan aplikasi yang anda gunakan tidak masalah karena yang penting adalah kodingnya dan yang pasti harus .Net.

2. Tambahkan TextBox, Button dan Label pada Form1

Lihat contoh form dibawah ini:
Fungsi Terbilang Bahasa Indonesia VB.Net, Form terbilang VB.Net
Fungsi Terbilang Bahasa Indonesia VB.Net

Gambar diatas terdapat 2 buah textbox yang mana properti dari kedua textbox tersebut berbeda. Ini dia yang bikin beda :

Textbox1 hanya untuk single line sedangkan textbox2 untuk multiline sehingga properti textbox2 diatur menjadi Multiline = True.

3. Tambahkan 1 Module ke dalam project

Menambahkan module kedalam projek sangat menguntungkan karena kita bisa memanggilnya dari form1 dan dari form yang lainnya sehingga menghemat perulangan koding.

Dalam module tersebut kita akan menambahkan kode dibawah ini :

Module Module1
    Private _Kamus As SortedDictionary(Of Integer, String)
    Private _ArGroup() As String = {"", " Ribu", " Juta", " Milyar", " Triliun"}

    Private Sub InitializeKamus()
        _Kamus = New SortedDictionary(Of Integer, String)
        _Kamus.Clear()
        _Kamus.Add(0, "")
        _Kamus.Add(1, " Satu")
        _Kamus.Add(2, " Dua")
        _Kamus.Add(3, " Tiga")
        _Kamus.Add(4, " Empat")
        _Kamus.Add(5, " Lima")
        _Kamus.Add(6, " Enam")
        _Kamus.Add(7, " Tujuh")
        _Kamus.Add(8, " Delapan")
        _Kamus.Add(9, " Sembilan")
        _Kamus.Add(10, " Sepuluh")
        _Kamus.Add(11, " Sebelas")
        _Kamus.Add(100, " Seratus")
    End Sub

    Public Function Terbilang(Bilangan As Double) As String
        Dim sRet As String = ""
        Dim sMinus As String = ""
        Dim BilCacah As Double = 0
        Dim BilPecahan As Integer = 0


        InitializeKamus()

        Try
            If Bilangan < 0 Then sMinus = "Minus "

            Dim grp() As String = Split(Math.Abs(Bilangan).ToString(System.Globalization.NumberFormatInfo.CurrentInfo), System.Globalization.NumberFormatInfo.CurrentInfo.NumberDecimalSeparator)
            If grp.Length > 1 Then
                BilCacah = CDbl(grp(0))
                BilPecahan = CInt(grp(1))
            Else
                BilCacah = Bilangan
            End If

            Dim triple() As String = Split(BilCacah.ToString("#,##0", System.Globalization.NumberFormatInfo.CurrentInfo), System.Globalization.NumberFormatInfo.CurrentInfo.NumberGroupSeparator)
            Array.Reverse(triple)

            For i As Integer = triple.Length - 1 To 0 Step -1
                sRet = sRet & BacaGroupAngka(triple(i), False, IIf(i > 5, i - 5 + 1, i))
            Next

            If BilPecahan > 0 Then
                sRet = sRet & " Koma" & BacaGroupAngka(BilPecahan, True)
            End If

            sRet = sMinus & sRet

        Catch ex As Exception
            MsgBox(ex.Message, vbOKOnly, "Parsing Bilangan")

        End Try

        _Kamus.Clear()
        _Kamus = Nothing

        Return sRet.Trim
    End Function

    Private Function BacaGroupAngka(ByVal Angka As Integer, _
                                    Optional IsPecahan As Boolean = False, _
                                    Optional iGroup As Byte = 0) As String
        Dim sRet As String = ""
        Dim sAngka As String = Angka.ToString("000")

        Select Case IsPecahan
            Case True
                Try
                    For i As Integer = 0 To sAngka.Length - 1
                        If CInt(sAngka.Substring(i, 1)) = 0 Then
                            sRet = sRet & "Nol"
                        Else
                            sRet = sRet & _Kamus(CInt(sAngka.Substring(i, 1)))
                        End If
                    Next
                Catch ex As Exception
                    MsgBox(ex.Message, vbOKOnly, "Baca Pecahan")
                End Try
            Case Else
                Try
                    If Angka = 1 And iGroup = 1 Then
                        sRet = " Seribu"
                    ElseIf _Kamus.ContainsKey(Angka) Then
                        sRet = _Kamus(Angka) & _ArGroup(iGroup)
                    Else
                        Dim Satuan As String = _Kamus(CInt(sAngka.Substring(2, 1)))
                        Dim puluhan As String = ""
                        Dim ratusan As String = ""

                        If _Kamus.ContainsKey(CInt(sAngka.Substring(1, 2))) Then
                            puluhan = _Kamus(CInt(sAngka.Substring(1, 2)))
                        Else
                            If CInt(sAngka.Substring(1, 1)) = 0 Then
                                puluhan = Satuan
                            ElseIf CInt(sAngka.Substring(1, 1)) = 1 Then
                                puluhan = Satuan & " Belas"
                            Else
                                puluhan = _Kamus(CInt(sAngka.Substring(1, 1))) & " Puluh" & Satuan
                            End If
                        End If

                        If CInt(sAngka.Substring(0, 1)) = 0 Then
                            ratusan = puluhan
                        ElseIf CInt(sAngka.Substring(0, 1)) = 1 Then
                            ratusan = " Seratus" & puluhan
                        Else
                            ratusan = _Kamus(CInt(sAngka.Substring(0, 1))) & " Ratus" & puluhan
                        End If

                        sRet = ratusan & _ArGroup(iGroup)
                    End If
                Catch ex As Exception
                    MsgBox(ex.Message, vbOKOnly, "Baca Bilangan Bulat")
                End Try
        End Select

        Return sRet
    End Function
End Module

Note : Copy Seluruh kode diatas lalu tempelkan kedalam module.



4. Klik 2x pada Button1, lalu masukkan kode

Kita akan menggunakan bantuan button pada event click, untuk memanggil fungsi terbilang yang ada di module1. Lihat koding dibawah ini :

Try
     ' menampilkan hasil dari fungsi terbilang ke textbox 2 berdasarkan angka dari textbox1
     Dim angka As Double = 0
     If Double.TryParse(TextBox1.Text, angka) Then
         TextBox2.Text = Terbilang(angka)
     End If
Catch ex As Exception
      MsgBox(ex.Message)
End Try
Copy kode diatas dan masukkan kedalam event Click Button1, atau seperti gambar dibawah ini:
Contoh penempatan kode, event click vb.net
Contoh Penempatan kode pada Button1

5. Jalankan Program Atau F5


Pada tahap ini tolong dipastikan kode diatas sudah nempel pada program dan tidak ada error sehingga anda bisa memulai untuk mengetest-nya.

Cara menggunakannya :
  • Masukkan angka atau nominal pada textbox1 (bukan huruf)
  • Klik button1
  • Lihat hasilnya pada textbox2.

Lihat contoh hasil dari program diatas :
Fungsi Terbilang Bahasa Indonesia VB.Net, Result Fungsi terbilang VB.Net
Hasil Program Fungsi Terbilang Bahasa Indonesia VB.Net

Silahkan kembangkan koding diatas jika memang dirasa kurang lengkap, atau juga silahkan tambahkan event keypress jika tidak ingin klik pada button. Intinya silahkan explore lagi koding diatas.

Untuk sementara waktu sampai disini dulu tutorial Fungsi Terbilang Bahasa Indonesia VB.Net lain waktu saya akan buat lagi artikel tentang webservice yang mana webservice tersebut sudah saya praktekkan untuk pertukaran data antara perusahaan dan intansi pemerintah.

Demikian tutorial ini, selamat mencoba, semoga bermanfaat.

Tags

0 Komentar untuk "Ini Dia Fungsi Terbilang Bahasa Indonesia VB.Net"